Le format dtas (Stata 18)

Author

Affiliation

Marc Thévenin

Ined

Abstract

La version 18 de Stata a implémenté un nouveau format, associé aux frames, le format .dtas. Il permet d’enregistrer toutes les frames actives, qu’elles soit liées ou non.

Par l’exemple.

• On charge la base auto (nom de la frame = default).
• On renomme la frame en auto.
• On génère la frame prix qui comprend la variable price de la frame auto.

sysuse auto 
frame rename default auto
frame put price foreign, into(prix)

frame dir

(1978 automobile data)
  auto  74 x 12; 1978 automobile data
* prix  74 x 2; 1978 automobile data

Note: Frames marked with * contain unsaved data.

• La frame prix est transformé en une frame indicateurs avec la commande collapse.

frame prix {
collapse price, by(foreign)
list
}

     +--------------------+
     |  foreign     price |
     |--------------------|
  1. | Domestic   6,072.4 |
  2. |  Foreign   6,384.7 |
     +--------------------+

• On enregistre les deux frames avec la commande frames save au format dtas.
• Cette collection de frames est appelée auto_prix.

frames save "auto_prix.dtas", frames(_all) replace

file auto_prix.dtas saved

• On ferme les frames
• On ouvre la collection auto_prix.dtas

frame reset

frames use "auto_prix.dtas", frames(_all)
frame dir
frame change prix
list

  auto  74 x 12; 1978 automobile data
  prix  2 x 2; 1978 automobile data
  auto     74 x 12; 1978 automobile data
  default  0 x 0
  prix     2 x 2; 1978 automobile data

     +--------------------+
     |  foreign     price |
     |--------------------|
  1. | Domestic   6,072.4 |
  2. |  Foreign   6,384.7 |
     +--------------------+

• On ferme la collection.
• On ouvre seulement la frame prix de la collection auto_prix.dtas.

frame reset

frames use "auto_prix.dtas", frames(prix)
frame dir

  prix  2 x 2; 1978 automobile data
  default  0 x 0
  prix     2 x 2; 1978 automobile data